home *** CD-ROM | disk | FTP | other *** search
/ Wonky Flux Batch 2019 02 / Wonky_Flux_Batch_2019-02.zip / Wonky Flux Batch 2019-02 / 063 - Wasteland Side 1.dsk / PRINT.bas < prev    next >
BASIC Source File  |  2019-02-17  |  27KB  |  375 lines
  1. 1  ONERR  GOTO 375
  2. 2  TEXT : GOTO 346
  3. 3  CALL 54572: FOR II = 512 TO 768: IF  PEEK(II) < >0  THEN  NEXT 
  4. 4 II$ = X$:AG =  VAL(II$) + PEEK(131) +256 * PEEK(132): POKE AG,II -512: POKE AG +1,0: POKE AG +2,2:II$ =  MID$ (II$,1):II = 768: NEXT : RETURN 
  5. 5 TC = TC +1: IF Y% <1  THEN  RETURN 
  6. 6  PRINT PR$;: IF RF <1  THEN  PRINT 
  7. 7  RETURN 
  8. 8 TC = TC +1: IF Y% >0  THEN  PRINT 
  9. 9  RETURN 
  10. 10 Y% = 1:G% = 0:LP% = 0:ML = 55:MM = ML +3:P% = 1
  11. 11  GOSUB 56: GOSUB 44: IF I$ = S$  THEN P% = 3:PA% = 1:MM = 24: GOTO 14
  12. 12  GOSUB 46: GOSUB 48: IF  PEEK(64435) < >6  OR  PEEK(64448) < >0  THEN  GOSUB 52
  13. 13  GOSUB 61: IF I$ = N$  THEN 11
  14. 14 ML = MM -3:DM% = 16:MX% = 78:HH% = 80:H2% = HH%/2:LL% = 53
  15. 15  GOSUB 158: GOSUB 370:Y% = 1: GOSUB 290: GOSUB 362:PP = 2
  16. 16 TC = 0: GOSUB 8: VTAB 1
  17. 17 WO$ = "WILL OF " +V$(1):I$ = WO$: GOSUB 139
  18. 18  GOSUB 8: GOSUB 8:I$ = J$ +"I, " +V$(1) +", A RESIDENT OF " +SN$ +CY$
  19. 19 I$ = I$ +", DECLARE THAT THIS IS MY WILL.": GOSUB 123
  20. 20 NA = 17:AC% = 0:CL = TC: FOR IA = 1 TO NA
  21. 21  IF IA < >4  THEN 29
  22. 22  IF G <1  OR V$(24) < >Y$  THEN 33
  23. 23  FOR IG = 1 TO G:AC% = AC% +1:TC = 0:NO% = 0:Y% = 0: GOSUB 112: GOSUB 173
  24. 24  IF NO% >0  THEN AC% = AC% -1: GOTO 28
  25. 25  IF CL +TC >ML  THEN  GOSUB 355
  26. 26 TC = 0:Y% = 1: GOSUB 112: GOSUB 173
  27. 27 CL = CL +TC
  28. 28  NEXT : GOTO 33
  29. 29 AC% = AC% +1:TC = 0:NO% = 0:Y% = 0: GOSUB 110
  30. 30  IF NO% >0  THEN AC% = AC% -1: GOTO 33
  31. 31  IF CL +TC >ML  THEN  GOSUB 355
  32. 32 TC = 0:Y% = 1: GOSUB 110:CL = CL +TC
  33. 33  NEXT 
  34. 34 LP% = 1: GOSUB 355
  35. 35  GOSUB 371: GOSUB 374
  36. 36  GOSUB 374:PP = 0: GOSUB 121:V = 8:H = 10: GOSUB 155: PRINT "YOU MAY NOW ENTER "DQ$P$DQ$
  37. 37 V = V +2:H = 8: GOSUB 155: PRINT "TO PRINT YOUR WILL AGAIN"
  38. 38 F2% = 4: GOSUB 74
  39. 39  IF I$ = Q$  THEN  GOSUB 158:V = 10:H = 10: GOSUB 155: PRINT "SO LONG!": END 
  40. 40  IF I$ = P$  THEN 10
  41. 41  IF I$ = RR$  THEN  PRINT D$;"RUN STARTUP"
  42. 42  GOTO 10
  43. 43  END 
  44. 44  GOSUB 121:V = 3:H = 6: GOSUB 155: PRINT "IF YOU HAVE AN 80-COLUMN CARD":V = V +2:H = 4: GOSUB 155: PRINT "IN SLOT 3, YOU MAY PREVIEW YOUR":V = V +2: GOSUB 155: PRINT "WILL ON THE SCREEN."
  45. 45 V = V +2: GOSUB 155: PRINT ">"TP$DQ$P$DQ$" TO PRINT YOUR WILL":V = V +2:H = H +7: GOSUB 155: PRINT DQ$S$DQ$" TO SEE IT ON YOUR SCREEN";:F2% = 5: GOSUB 74: RETURN 
  46. 46  GOSUB 121:V = 3:H = 14: GOSUB 155: PRINT TP$:V = V +2:H = 4: GOSUB 155: PRINT DQ$;C$;DQ$;" IF YOU HAVE CONTINUOUS PAPER":V = V +2: GOSUB 155: PRINT DQ$S$DQ$" TO PRINT ONE SHEET AT A TIME";:F2% = 1: GOSUB 74:PA% = 1: IF I$ = S$  THEN PA% = 0
  47. 47  RETURN 
  48. 48  GOSUB 121:V = 3:H = 3: GOSUB 155: PRINT "CURRENTLY PRINTING "MM" LINES PER PAGE":V = V +3: GOSUB 155: PRINT TP$DQ$Y$DQ$" IF THIS IS OK";:V = V +2:H = H +6: GOSUB 155: PRINT DQ$N$DQ$" TO CHANGE TO ANOTHER VALUE";
  49. 49 F2% = 2: GOSUB 74: IF I$ = Y$  THEN  RETURN 
  50. 50 V = 22:H = 3: GOSUB 155: PRINT TP$"NEW NUMBER OF LINES:";: GOSUB 64:MM =  VAL(I$): IF MM <10  OR MM >999  THEN  GOSUB 94: GOTO 50
  51. 51 ML = MM -3: GOTO 48
  52. 52  GOSUB 121:V = 3:H = 6: GOSUB 155: PRINT "IF YOUR PRINTER IS CONNECTED":V = V +2:H = 11: GOSUB 155: PRINT "TO SLOT #"P%" TYPE "DQ$Y$DQ$:V = V +2:H = H +1: GOSUB 155: PRINT "OTHERWISE TYPE "DQ$N$DQ$;
  53. 53 F2% = 2: GOSUB 74: IF I$ < >N$  THEN  RETURN 
  54. 54 V = 22:H = 3: GOSUB 155: PRINT TP$" NEW SLOT NUMBER:";: GOSUB 64: IF  VAL(I$) <0  OR  VAL(I$) >6  THEN  GOSUB 94: GOTO 52
  55. 55 P% =  VAL(I$): GOTO 52
  56. 56  GOSUB 121:V = 3:H = 3: GOSUB 155: PRINT " DO YOU WISH TO HAVE YOUR WILL":V = V +2: GOSUB 155: PRINT "NOTARIZED IN ADDITION TO HAVING IT":V = V +2: GOSUB 155: PRINT "WITNESSED?": IF FF <1  THEN 58
  57. 57 V = V +2: GOSUB 155: PRINT "(WE RECOMMEND THIS IF YOU LIVE IN":V = V +1: GOSUB 155: PRINT SN$".)":V = V -1
  58. 58 V = V +2: GOSUB 155: INVERSE : PRINT "->";: NORMAL : PRINT "SEE MANUAL PART 11A FOR DETAILS.":V = V +3: GOSUB 155: PRINT "ENTER:":V = V +1: GOSUB 155: PRINT DQ$Y$DQ$" TO PRINT WILL WITH NOTARY FORM":V = V +1: GOSUB 155
  59. 59  PRINT DQ$N$DQ$" IF YOU DON'T WANT TO NOTARIZE":F2% = 2: GOSUB 74:GG = 0: IF I$ = Y$  THEN GG = 1
  60. 60  RETURN 
  61. 61  IF P% = 3  THEN PA% = 1:MM = 24
  62. 62  GOSUB 121:V = 6:H = 15: GOSUB 155: PRINT TP$DQ$Y$DQ$:V = V +2:H = 6: GOSUB 155: PRINT "WHEN YOUR PRINTER IS READY":V = V +2:H = H +6: GOSUB 155: PRINT DQ$N$DQ$" TO RESET OPTIONS";
  63. 63 F2% = 2: GOSUB 74: RETURN 
  64. 64 X =  PEEK( -16368):V = 22:H = 28: GOSUB 155: PRINT UU$;UU$;: GOSUB 155:I$ = X$
  65. 65  GET T$: IF T$ = X$  THEN 65
  66. 66 A =  ASC(T$): IF A = 13  THEN  RETURN 
  67. 67 L =  LEN(I$): IF A <32  THEN 70
  68. 68  IF L >1  THEN  GOSUB 94: GOTO 65
  69. 69 I$ = I$ +T$: PRINT T$;: GOTO 65
  70. 70  IF A < >8  OR L <1  THEN 65
  71. 71  IF L <2  THEN I$ = X$: GOTO 73
  72. 72 I$ =  LEFT$(I$,L -1)
  73. 73  PRINT T$;UU$;T$;: GOTO 65
  74. 74 H = 3:V =  PEEK(37) +3: GOSUB 155: PRINT TP$DQ$RR$DQ$" TO RETURN TO MAIN PROGRAM":V = V +1: GOSUB 155: PRINT TP$DQ$Q$DQ$" TO QUIT":V = V +2: GOSUB 155: PRINT "  (DON'T FORGET "DQ$"RETURN"DQ$")":V = 22
  75. 75 I$ = X$
  76. 76  GOSUB 155:X =  PEEK( -16368): PRINT I$;
  77. 77  GET T$: IF T$ = X$  THEN 77
  78. 78 A =  ASC(T$): IF A >90  THEN A = A -32:T$ =  CHR$(A)
  79. 79  IF A = 13  OR A = 27  THEN 82
  80. 80  IF A = 8  THEN  GOSUB 89: GOTO 75
  81. 81 I$ = T$: GOTO 76
  82. 82  PRINT  CHR$(1);:VA% =  VAL(I$)
  83. 83  IF F2% = 0  OR I$ = Q$  OR I$ = RR$  THEN 91
  84. 84  IF F2% = 1  AND (I$ = C$  OR I$ = S$)  THEN 91
  85. 85  IF F2% = 2  AND (I$ = Y$  OR I$ = N$)  THEN 91
  86. 86  IF F2% = 4  AND (I$ = Q$  OR I$ = RR$  OR I$ = P$)  THEN 91
  87. 87  IF F2% = 5  AND (I$ = S$  OR I$ = P$)  THEN 91
  88. 88  GOSUB 94: GOTO 75
  89. 89  IF I$ < >CR$  THEN  PRINT  CHR$(8);
  90. 90  PRINT SP$; CHR$(8);: RETURN 
  91. 91 X =  PEEK(SO):X =  PEEK(SO): IF I$ = Q$  THEN  HOME :V = 10:H = 15: GOSUB 155: PRINT "SO LONG...": END 
  92. 92  IF I$ = RR$  THEN  PRINT D$"RUN STARTUP"
  93. 93  RETURN 
  94. 94  FOR I = 1 TO 30:S =  PEEK(SO): NEXT : RETURN 
  95. 95 F$ = "WD": GOSUB 154: PRINT O$F$: PRINT R$F$: INPUT FI%: INPUT CH%: INPUT D: INPUT G: INPUT SN$: INPUT FF: INPUT CP: INPUT AG%: INPUT AN$: FOR I = 1 TO NV: GOSUB 3:V$(I) = II$: NEXT : PRINT K$: IF SN$ = "CALIFORNIA"  THEN CA% = 1
  96. 96  IF V$(13) < >NU$  AND V$(13) < >X$  THEN CY$ = QZ$ +V$(13)
  97. 97  IF  LEFT$(SN$,2) = "DI"  THEN DC% = 1:SN$ = "THE DISTRICT OF COLUMBIA": RETURN 
  98. 98 SN$ = SO$ +SN$: RETURN 
  99. 99 F$ = "F" + STR$(FF%):LF% = 38: PRINT O$F$",L"LF%
  100. 100  FOR I = 1 TO M%:I% = I
  101. 101  PRINT R$F$",R"I%: GOSUB 3
  102. 102  IF FF% = 1  THEN CH$(I) = II$
  103. 103  IF FF% = 2  THEN DI$(I) = II$
  104. 104  NEXT : PRINT K$F$: RETURN 
  105. 105  IF G <1  THEN  RETURN 
  106. 106 F$ = "F": PRINT O$F$",L240"
  107. 107  FOR IG = 1 TO G:IG% = 3 *IG -2
  108. 108  PRINT R$F$",R"IG%: GOSUB 3:GD$(IG) = II$: PRINT R$F$",R"IG% +1: GOSUB 3:GN$(IG) = II$: PRINT R$F$",R"IG% +2: GOSUB 3:GA$(IG) = II$: NEXT 
  109. 109  PRINT K$: RETURN 
  110. 110  GOSUB 112: ON IA GOSUB 159,161,165,173,184,285,181,264,183,194,209,213,228,218,282,188,238
  111. 111  RETURN 
  112. 112  GOSUB 8:I$ = X$:AC = AC%
  113. 113 A1% =  INT(AC/10):A0% = AC -10 *A1%
  114. 114  IF A1% <2  THEN 118
  115. 115 I$ = I$ +N2$(A1%): IF A0% = 0  THEN I$ = I$ +IE$: GOTO 120
  116. 116 I$ = I$ +Y$ +N1$(A0%): IF A0% <4  THEN  GOTO 120
  117. 117 I$ = I$ +"TH": GOTO 120
  118. 118 I$ = I$ +N1$(AC): IF (A0% <4  AND A1% = 0)  THEN  GOTO 120
  119. 119 I$ = I$ +"TH"
  120. 120 I$ = J$ +I$ +": ": RETURN 
  121. 121  TEXT : HOME :V = 1:H = 1: GOSUB 155: PRINT FR$;: FOR I = 1 TO 22:V = I:H = 1: GOSUB 155: PRINT "!";:H = 40: GOSUB 155: PRINT "!";: NEXT :V = 23:H = 1: GOSUB 155: PRINT FR$;: RETURN 
  122. 122 RF% = 1
  123. 123 MX = MX%
  124. 124 RF = 0:TE$ =  LEFT$(I$,MX)
  125. 125  IF I$ = X$  OR I$ = SP$  THEN 137
  126. 126  IF  LEN(I$) < = MX  THEN PR$ = I$:RF = RF%: GOSUB 5: GOTO 137
  127. 127 DM = MX -DM%: IF DM <1  THEN DM = 1
  128. 128 II = 0: FOR I = MX TO DM  STEP  -1: IF  MID$ (TE$,I,1) = SP$  THEN II = I:I = DM
  129. 129  NEXT 
  130. 130  IF II >0  THEN 134
  131. 131 PR$ = TE$ +"-": GOSUB 5
  132. 132  IF  LEN(I$) < = MX  THEN 137
  133. 133 I$ =  MID$ (I$,MX +1,255): GOTO 135
  134. 134 PR$ =  LEFT$(I$,II -1): GOSUB 5:I$ =  MID$ (I$,II +1,255)
  135. 135  IF  LEFT$(I$,1) = SP$  THEN I$ =  MID$ (I$,2,255): GOTO 135
  136. 136 MX = MX%: GOTO 124
  137. 137  IF RF% >0  THEN  PRINT SP$;:MX = MX% - LEN(PR$) -1: IF MX <1  THEN MX = 1
  138. 138 RF% = 0: RETURN 
  139. 139 LL =  LEN(I$): IF LL >76  THEN  GOSUB 123: RETURN 
  140. 140 HH = (80 -LL)/2 -1
  141. 141  IF HH <1  THEN HH = 1
  142. 142  IF HH >39  THEN HH = 39
  143. 143 PR$ =  LEFT$(SQ$,HH) +I$: GOSUB 5: RETURN 
  144. 144 TS$ = I$
  145. 145 LT% =  LEN(TS$): IF LT% <1  THEN  RETURN 
  146. 146 IM% = 0: FOR IJ = 1 TO LT%: IF  MID$ (TS$,IJ,1) = ";"  THEN IM% = IJ:IJ = LT%
  147. 147  NEXT : IF IM% <1  THEN I$ = TS$: GOSUB 139: RETURN 
  148. 148  IF IM% >1  THEN 151
  149. 149  GOSUB 8: IF LT% >1  THEN TS$ =  RIGHT$(TS$,LT% -1): GOTO 145
  150. 150  RETURN 
  151. 151 I$ =  LEFT$(TS$,IM% -1): GOSUB 139
  152. 152  IF  LEN(TS$) >IM%  THEN TS$ =  MID$ (TS$,IM% +1,255): GOTO 145
  153. 153  RETURN 
  154. 154  GOSUB 121:V = 11:H = 12: GOSUB 155: FLASH : PRINT ">";: NORMAL : PRINT "DISK DRIVE IN USE": VTAB 24: RETURN 
  155. 155  HTAB H
  156. 156  VTAB V: RETURN 
  157. 157  HTAB H: RETURN 
  158. 158  HOME : RETURN 
  159. 159  GOSUB 8:I$ = I$ +"I revoke all wills and codicils that I have previously made.": GOSUB 123
  160. 160  RETURN 
  161. 161  IF V$(3) < >Y$  THEN 345
  162. 162 I$ = I$ +"I am married": IF V$(4) < >X$  AND V$(4) < >NU$  THEN I$ = I$ +" to " +V$(4)
  163. 163 I$ = I$ +PD$: GOSUB 123
  164. 164  RETURN 
  165. 165  IF V$(5) < >Y$  OR CH% <1  THEN 345
  166. 166  IF Y% < = 0  THEN RN% = 0
  167. 167 S1$ = "one child":S2$ = " is": IF RN% >1  THEN S1$ =  STR$(RN%) +" children":S2$ = "s are"
  168. 168 I$ = I$ +"I have " +S1$ +" now living, whose name" +S2$ +": "
  169. 169  GOSUB 123:OF% = 0: GOSUB 334
  170. 170  IF CH% = 1  AND (CH$(1) < >X$  AND CH$(1) < >NU$)  THEN RN% = 1
  171. 171  IF RN% <1  THEN 345
  172. 172  RETURN 
  173. 173  GOSUB 8: IF GD$(IG) = X$  OR GN$(IG) = X$  OR GD$(IG) = NU$  OR GN$(IG) = NU$  OR GD$(IG) =  CHR$(1)  OR GN$(IG) =  CHR$(1)  THEN 345
  174. 174 I$ = I$ +"I make the following bequest of money or personal property:": GOSUB 123
  175. 175  GOSUB 8:I$ = "I give:": GOSUB 123:I$ = GD$(IG) +CO$: GOSUB 144
  176. 176  GOSUB 8:I$ = "to the following person or entity:": GOSUB 123:I$ = GN$(IG) +PD$: GOSUB 144
  177. 177  IF GA$(IG) = X$  OR GA$(IG) = NU$  THEN 180
  178. 178  GOSUB 8:I$ = "However, if this person or entity" +B$ +"I revoke the above bequest, which shall instead be made to:": GOSUB 123
  179. 179 I$ = GA$(IG) +PD$: GOSUB 144
  180. 180  RETURN 
  181. 181 S3$ = "all my real property, together with any insurance on that property, and subject to any encumbrances on it at the time of my death, including any mortgage, deed of trust, and real property taxes and assessments, "
  182. 182 S1$ = V$(10):S2$ = V$(8):E = 0: GOSUB 317: RETURN 
  183. 183 S3$ = "my residuary estate, i.e. the rest of my property not otherwise specifically disposed of by this will or in any other manner, ":S1$ = V$(9):S2$ = V$(7):E = 1: GOSUB 317: RETURN 
  184. 184 I$ = I$ +"If any beneficiary": IF V$(5) = Y$  THEN I$ = I$ +", other than my child": IF CH% >1  THEN I$ = I$ +"ren"
  185. 185  IF V$(5) = Y$  THEN I$ = I$ +","
  186. 186 I$ = I$ +" of any specific personal property bequest made by this will" +B$ +"and no alternative beneficiary": GOSUB 122
  187. 187 I$ = "has been named in this will to receive that bequest, such bequest shall pass into my residuary estate.": GOSUB 124: RETURN 
  188. 188  IF V$(17) = X$  OR V$(17) = NU$  THEN 345
  189. 189 I$ = I$ +"I nominate": GOSUB 123:I$ = V$(17): GOSUB 144:I$ = "as executor of this will, to serve without bond.": GOSUB 123
  190. 190  IF V$(18) = X$  OR V$(18) = NU$  THEN 193
  191. 191  GOSUB 8:I$ = "If " +V$(17) +" shall for any reason fail to qualify or cease to act as executor, I nominate ": GOSUB 139
  192. 192 I$ = V$(18) +CO$: GOSUB 144:I$ = "also to serve as executor without bond.": GOSUB 123
  193. 193  RETURN 
  194. 194  GOSUB 8: IF CA% >0  THEN I$ = I$ +"I direct that my executor petition the court for an order to adminsiter my estate under the provisions of the Independent Administration of Estates Act.": GOSUB 123: RETURN 
  195. 195 I$ = I$ +"I hereby grant to my executor the following powers, to be exercised as he or she deems to be in the best interests of my estate:": GOSUB 123
  196. 196 I$ = J$ +"1) To retain property without liability for loss or depreciation resulting from such retention.": GOSUB 123
  197. 197 I$ = J$ +"2) To dispose of property by public or private sale, or exchange, or otherwise, and receive and administer the proceeds as a part of my estate.": GOSUB 123:S1$ = " bonds, notes, stocks or other securities"
  198. 198 I$ = J$ +"3) To vote stock, to exercise any option or privilege to convert" +S1$ +" belonging to my estate into other" +S1$ +",": GOSUB 122
  199. 199 I$ = "and to exercise all other rights and privileges of a person owning similar property in his own right.": GOSUB 124
  200. 200 I$ = J$ +"4) To lease any real property that may at any time form part of my estate.": GOSUB 123
  201. 201 I$ = J$ +"5) To abandon, adjust, arbitrate, compromise, sue on or defend and otherwise deal with and settle claims in favor of or against my estate.": GOSUB 123
  202. 202 I$ = J$ +"6) To continue or participate in any business which is a part of my estate, and to effect incorporation, dissolution or other change in the form of organization of the business.": GOSUB 123
  203. 203 I$ = J$ +"7) To pay all just debts, and all taxes that may, by reason of my death, be assessed against my estate or any portion of it, whether passing by probate or not,": GOSUB 122
  204. 204 I$ = "provided that such debts and taxes shall be first satisfied out of my residuary estate.": GOSUB 124: IF P% = 3  AND Y% >0  THEN I$ = A$ + STR$(G%): GOSUB 373
  205. 205 I$ = J$ +"8) To do all other acts, which in his or her judgment may be necessary or appropriate for the proper and advantageous management, investment and distribution of my estate.": GOSUB 123
  206. 206  GOSUB 8:S1$ = " powers, authority and discretion ":I$ = J$ +"The foregoing" +S1$ +"granted to my executor are intended to be in addition to the" +S1$ +"vested in him or her by operation of law": GOSUB 122
  207. 207 I$ = "by virtue of his or her office, and may be exercised as often as is deemed necessary or advisable, without application to or approval by any court in any jurisdiction.": GOSUB 124
  208. 208  RETURN 
  209. 209 I$ = I$ +"If any beneficiary under this will, in any manner, directly or indirectly, contests or attacks this will or any of its provisions,": GOSUB 122
  210. 210 I$ = "any share or interest in my estate given to the contesting beneficiary under this will is revoked and shall be disposed of in the same manner provided herein as if that contesting beneficiary had predeceased me without issue."
  211. 211  GOSUB 124
  212. 212  RETURN 
  213. 213  IF V$(3) < >Y$  THEN 345
  214. 214 I$ = I$ +"If my spouse and I should die simultaneously, or under such circumstances as to render it difficult or impossible"
  215. 215  GOSUB 122
  216. 216 I$ = "to determine who predeceased the other, I shall be conclusively presumed to have survived my spouse for purposes of this will.": GOSUB 124
  217. 217  RETURN 
  218. 218  IF V$(6) < >Y$  OR V$(14) = X$  OR V$(14) = NU$  THEN 345
  219. 219 I$ = I$ +"If at my death any of my children are minors, I recommend that": GOSUB 123
  220. 220 I$ = V$(14): GOSUB 144
  221. 221 I$ = "be appointed Guardian of the Estate of the minor child or children.": GOSUB 123
  222. 222  IF V$(15) = X$  OR V$(15) = NU$  THEN 226
  223. 223 I$ = J$ +"If " +V$(14) +" shall for any reason fail to qualify or cease to act as Guardian of the Estate, I appoint:": GOSUB 123
  224. 224 I$ = V$(15): GOSUB 144
  225. 225 I$ = "to act as such guardian instead.": GOSUB 123
  226. 226  GOSUB 8:I$ = J$ +"I request that no bond be required of any guardian named in this section.": GOSUB 123
  227. 227  RETURN 
  228. 228  IF V$(6) < >Y$  OR V$(11) = X$  OR V$(11) = NU$  THEN 345
  229. 229 I$ = I$ +"If 45 days after my death there is no living person who is entitled by law to the custody of my minor child or children and who is available to assume such custody, I recommend that": GOSUB 123
  230. 230 I$ = V$(11): GOSUB 144
  231. 231 I$ = "be appointed as personal guardian of my minor child or children.": GOSUB 123
  232. 232  IF V$(12) = X$  OR V$(12) = NU$  THEN 236
  233. 233 I$ = J$ +"If " +V$(11) +" shall for any reason fail to qualify or cease to act as guardian, I recommend that:": GOSUB 123
  234. 234 I$ = V$(12): GOSUB 144
  235. 235 I$ = "be appointed to act as such guardian instead.": GOSUB 123
  236. 236  GOSUB 8:I$ = J$ +"I request that no bond be required of any guardian named in this section.": GOSUB 123
  237. 237  RETURN 
  238. 238 TD$ = " this _______day of __________, 19__": GOSUB 8:I$ = J$ +"I, " +V$(1) +", the testator, sign my name to this instrument, consisting of " + STR$(G% +1) +" pages, including this page signed by me," +TD$ +".": GOSUB 123
  239. 239 I$ = J$: IF GG >0  THEN I$ = I$ +"Being first duly sworn, "
  240. 240 I$ = I$ +"I hereby declare ": IF GG >0  THEN I$ = I$ +"to the undersigned authority "
  241. 241 I$ = I$ +"that I sign and execute this instrument as my last will, that I sign it willingly, and that I execute it as my free and voluntary act for the purposes therein expressed.": GOSUB 123
  242. 242 S1$ = " of the age of majority or otherwise legally empowered to make a will, and under no constraint or undue influence.":I$ = J$ +"I declare that I am" +S1$: GOSUB 123
  243. 243  GOSUB 8:I$ = H$: GOSUB 139:I$ = "(Signed)": GOSUB 139
  244. 244  IF P% < >3  THEN  GOSUB 8
  245. 245 I$ = J$ +"We, the witnesses, sign our names to this instrument, ": IF GG >0  THEN I$ = I$ +"being first duly sworn, "
  246. 246 I$ = I$ +"and do hereby declare ": IF GG >0  THEN I$ = I$ +"to the undersigned authority, "
  247. 247 I$ = I$ +"that the testator signs and executes this instrument as his last will and that he signs it willingly.": GOSUB 123
  248. 248 I$ = J$ +"Each of us, in the presence of the testator, and in the presence of each other, hereby signs this will as witness to the testator's signing.": GOSUB 123
  249. 249 I$ = J$ +"To the best of our knowledge the testator is" +S1$: GOSUB 123
  250. 250  IF P% = 3  AND Y% >0  THEN G% = G% +1:I$ = A$ + STR$(G%): GOSUB 373: GOTO 252
  251. 251  GOSUB 8
  252. 252  IF P% < >3  THEN  GOSUB 8
  253. 253 I$ = J$ +"We declare, under penalty of perjury, that the foregoing is true and correct," +TD$ +", at " + LEFT$(H$,15): GOSUB 123
  254. 254 I$ =  LEFT$(H$,24) +"residing at:" +H$: FOR J = 1 TO 3: GOSUB 8: GOSUB 139: GOSUB 8: NEXT 
  255. 255  IF GG <1  THEN  RETURN 
  256. 256  IF P% < >3  THEN  GOSUB 8: GOSUB 8
  257. 257 I$ = "*  FOR NOTARIZATION  *": GOSUB 139: IF P% < >3  THEN  GOSUB 8
  258. 258 I$ = SO$ + LEFT$(H$,20) +QZ$ + LEFT$(H$,20): GOSUB 123: GOSUB 8:I$ = J$ +"Subscribed, sworn to and acknowledged before me by": GOSUB 123
  259. 259 I$ = V$(1): GOSUB 139
  260. 260 I$ = "and " + LEFT$(H$,16) +CS$ + LEFT$(H$,16) +", and " + LEFT$(H$,16) +", witnesses, personally known to me (or proved to me on the basis of satisfactory evidence to be the persons)," +TD$ +".": GOSUB 124
  261. 261  IF P% < >3  THEN  GOSUB 8: GOSUB 8
  262. 262 I$ = "SIGNED:" + LEFT$(H$,19): GOSUB 139: IF P% < >3  THEN  GOSUB 8
  263. 263 I$ =  LEFT$(H$,30): GOSUB 139:I$ = "Official Capacity of Officer": GOSUB 139: RETURN 
  264. 264  IF (V$(5) < >Y$  OR CH% <1)  AND (V$(19) < >Y$  OR D <1)  THEN 345
  265. 265  IF Y% < = 0  THEN RN% = 0
  266. 266 S1$ = " person": IF RN% >1  THEN S1$ =  STR$(RN%) +S1$ +"s"
  267. 267 I$ = I$ +"I hereby leave $1.00 to each of the following " +S1$ +":": GOSUB 123
  268. 268  IF CH% <1  OR V$(5) < >Y$  THEN 270
  269. 269 OF% = 0: GOSUB 334
  270. 270  IF D <1  OR V$(19) < >Y$  THEN 277
  271. 271  FOR J = 1 TO D:I$ = DI$(J): IF I$ = X$  OR I$ = NU$  THEN 276
  272. 272  IF Y% < = 0  THEN RN% = RN% +1:JL = J
  273. 273  IF J <JL  THEN I$ = I$ +CO$: GOTO 275
  274. 274 I$ = I$ +PD$
  275. 275  GOSUB 139
  276. 276  NEXT 
  277. 277  GOSUB 8:I$ = "This bequest is in addition to and not instead of any other gift, bequest, or devise that this will makes to such child, children, or grandchildren.": GOSUB 139
  278. 278  IF D = 1  AND CH% = 0  AND (DI$(1) < >X$  AND DI$(1) < >NU$)  THEN RN% = 1
  279. 279  IF CH% = 1  AND D = 0  AND (CH$(1) < >X$  AND CH$(1) < >NU$)  THEN RN% = 1
  280. 280  IF RN% <1  THEN 345
  281. 281  RETURN 
  282. 282 I$ = I$ +"If any person not my child who receives property under this will is a minor at the time of distribution, I direct": GOSUB 122
  283. 283 I$ = "my executor to distribute the property to the minor's guardian under the provisions of the Uniform Gifts to Minors Act, or the Uniform Transfers to Minors Act, enacted by "
  284. 284 I$ = I$ +SN$ +", if either is applicable.": GOSUB 124: RETURN 
  285. 285  IF V$(5) < >Y$  OR CH% <1  THEN 345
  286. 286 I$ = I$ +"If any of my children" +B$ +"specific personal property bequests made to them by this will for which an alternative beneficiary has": GOSUB 122
  287. 287 I$ = "not been named shall be given to the deceased child's or children's living children in equal shares.": GOSUB 124
  288. 288 I$ = J$ +"In the event no alternative beneficiary has been named in this will to recieve the bequest, and my deceased child has left no children of his or her own, such bequest shall pass into my residuary estate.": GOSUB 123
  289. 289  RETURN 
  290. 290  GOSUB 8:I$ = " IMPORTANT NOTES": GOSUB 139:I$ = "BEFORE" +E$: GOSUB 123
  291. 291 I$ = U$: GOSUB 123
  292. 292 I$ = J$ +"Read your will carefully.  Is everything printed as you intended?  Do you understand everything in it?  See Part 13 of the manual if anything isn't clear.": GOSUB 123
  293. 293  GOSUB 8:I$ = "WHILE" +E$: GOSUB 123
  294. 294 I$ = U$: GOSUB 123
  295. 295 I$ = J$ +"1. For your will to be valid you must be of sound mind and of the age specified by your state. See manual Part 2.": GOSUB 123
  296. 296 I$ = "2. You must say to the witnesses that you intend this to be your will. Initial and date each page where indicated. Then sign the last page in the presence of the witnesses. Use exactly the form of your name printed on the will."
  297. 297  GOSUB 8:I$ = J$ +I$: GOSUB 123
  298. 298  IF P% = 3  THEN I$ = CP$: GOSUB 373
  299. 299  GOSUB 8:I$ = J$ +"3. We suggest you have 3 witnesses, even though 2 are enough in many states. They should be in your and each other's presence when you sign the will.": GOSUB 122
  300. 300 I$ = "They should state that they realize you intend this to be your will and they should then sign the will in the space indicated for witnesses, and include their addresses.": GOSUB 124
  301. 301  IF GG >0  THEN  GOSUB 8:I$ = J$ +"4. You have chosen to do this before a notary.": GOSUB 123
  302. 302  GOSUB 8
  303. 303 I$ = "AFTER" +E$: GOSUB 123:I$ = U$: GOSUB 123
  304. 304 I$ = J$ +"Keep your will in a safe place, where it can be readily found.  You may make photocopies, but only the signed original can be probated.": GOSUB 123
  305. 305  IF P% < >3  THEN  GOSUB 8
  306. 306 I$ = J$ +"If there are major changes in your life, you should make, sign, and have witnessed a new will. Destroy the original of your old will and all copies. Changes that make it wise for you to make a new will include:": GOSUB 122
  307. 307 I$ = "having or adopting a child, moving to another state, the death of anyone named in your will, a change of marital status, and a change in the property you own. See manual Part 12 for a complete list.": GOSUB 124
  308. 308  GOSUB 8:I$ = "WillWriter, Copyright 1985 by Legisoft Inc.": GOSUB 139
  309. 309 I$ = "Nolo Press, 950 Parker St., Berkeley, CA 94710": GOSUB 139
  310. 310  IF P% = 3  THEN I$ = CP$: GOSUB 373
  311. 311  RETURN 
  312. 312 I1$ = "If any beneficiary named to receive this property" +B$ +"his or her share shall pass to the remaining surviving beneficiaries named above to receive this property."
  313. 313 I2$ = "If there are no such surviving beneficiaries, this property shall pass to:": RETURN 
  314. 314 I1$ = "If any child named to receive this property" +B$ +"that child's living children shall take that child's share in equal shares. If a child named to receive this property"
  315. 315 I2$ = B$ +"and leaves no children of his or her own, that child's share shall be divided in equal shares among any other surviving children named above to receive this property."
  316. 316 I3$ = "If there are no such surviving children, the deceased child's share shall pass to:": RETURN 
  317. 317  IF S1$ = X$  OR S1$ = NU$  THEN  POP : GOTO 345
  318. 318 I$ = I$ +"I give " +S3$ +"to:":FR = 0: IF S2$ = X$  OR S2$ = NU$  THEN FR = 1
  319. 319  GOSUB 123: IF S1$ = S$  THEN I$ = MS$ +PD$: GOSUB 139:ID = 1: GOTO 322
  320. 320  IF S1$ = C$  THEN I$ = TC$: GOSUB 139:ID = 2:OF% = 1: GOSUB 334: GOTO 322
  321. 321 I$ = S1$ +PD$: GOSUB 144:ID = 3
  322. 322  IF ID < >1  THEN 325
  323. 323  IF FR >0  AND E >0  THEN  RETURN 
  324. 324 I$ = J$ +"If " +MS$ +B$ +"then his or her share of this property shall pass to:": GOSUB 123: GOTO 330
  325. 325  IF ID < >2  THEN  GOTO 328
  326. 326  GOSUB 314:I$ = J$ +I1$: GOSUB 122:I$ = I2$: GOSUB 124: IF FR >0  AND E >0  THEN  RETURN 
  327. 327 I$ = J$ +I3$: GOSUB 123: GOTO 330
  328. 328  GOSUB 312:I$ = J$ +I1$: IF FR >0  AND E >0  THEN  GOSUB 123: RETURN 
  329. 329  GOSUB 122:I$ = I2$: GOSUB 124
  330. 330  IF FR >0  THEN I$ = "my residuary estate.": GOSUB 139: RETURN 
  331. 331  IF S2$ = S$  THEN I$ = MS$ +PD$: GOSUB 139: RETURN 
  332. 332  IF S2$ < >C$  THEN I$ = S2$ +PD$: GOSUB 144: RETURN 
  333. 333 I$ = TC$: GOSUB 139:OF% = 1: GOSUB 334: RETURN 
  334. 334  IF Y% < = 0  THEN RN% = 0
  335. 335  IF V$(20) < >Y$  THEN OF% = 0
  336. 336  FOR J = 1 TO CH%:I$ = CH$(J)
  337. 337  IF I$ = X$  OR I$ = NU$  OR I$ = M$  OR (OF% >0  AND  LEFT$(I$,1) = M$)  THEN 343
  338. 338  IF  LEFT$(I$,1) = M$  THEN I$ =  MID$ (I$,2, LEN(I$) -1): GOTO 337
  339. 339  IF Y% < = 0  THEN RN% = RN% +1:JL% = J
  340. 340  IF J <JL%  THEN I$ = I$ +CO$: GOTO 342
  341. 341 I$ = I$ +PD$
  342. 342  GOSUB 139
  343. 343  NEXT :TC$ = "my child": IF RN% >1  THEN TC$ = "the following of my children, in equal shares:"
  344. 344  RETURN 
  345. 345 NO% = 1: RETURN 
  346. 346 D$ =  CHR$(4):O$ = D$ +"OPEN":R$ = D$ +"READ":K$ = D$ +"CLOSE":M$ =  CHR$(1):N2$(2) = "TWENT":N2$(3) = "THIRT":CS$ = ", ":MS$ = "my spouse":CP$ = "(Cover Page)":A$ = "Screen ":E$ = " YOU SIGN:"
  347. 347 NV = 28:J$ = "     ":UU$ = ".":SQ$ = "                                       ":U$ = "---------------":FR$ =  LEFT$(U$ +U$ +U$,40):H$ = "______________________________________":SO$ = "THE STATE OF ":QZ$ = ", COUNTY OF "
  348. 348  DIM V$(NV),N1$(20),CH$(17),DI$(17),GD$(17),GN$(17),GA$(17): FOR I = 1 TO 9: READ N0$(I): NEXT : DATA "ONE","TWO","THREE","FOUR","FIVE","SIX","SEVEN","EIGHT","NINE"
  349. 349  FOR I = 1 TO 20: READ N1$(I): NEXT : DATA "FIRST","SECOND","THIRD","FOUR","FIF","SIX","SEVEN","EIGH","NIN","TEN","ELEVEN","TWELF","THIRTEEN","FOURTEEN","FIFTEEN","SIXTEEN","SEVENTEEN","EIGHTEEN","NINETEEN","TWENTIE"
  350. 350 X$ = "":Q$ = "Q":P$ = "P":RR$ = "R":B$ = " fails to survive me by 45 days, ":Y$ = "Y":N$ = "N":C$ = "C":CC$ = "c":S$ = "S":SS$ = "s":SP$ = " ":DQ$ =  CHR$(34):IE$ = "IETH":PD$ = ".":CO$ = ",":TP$ = "ENTER ":NU$ = "-NOT USED-"
  351. 351  GOSUB 95: IF CH% >0  THEN M% = CH%:FF% = 1: GOSUB 99
  352. 352  IF D >0  THEN M% = D:FF% = 2: GOSUB 99
  353. 353  IF G >0  THEN  GOSUB 105
  354. 354 MS$ = MS$ +", " +V$(4):SO =  -16336: GOTO 10
  355. 355  IF CL > = ML  THEN  PRINT : GOTO 357
  356. 356  HTAB 1: FOR I = 1 TO ML -CL +1: PRINT "//": NEXT 
  357. 357 Y% = 1:G% = G% +1: IF P% = 3  THEN 360
  358. 358 I$ = "Page " + STR$(G%): IF LP% <1  THEN I$ = I$ +"   Initials:________    Date:__________"
  359. 359  GOTO 361
  360. 360 I$ = A$ + STR$(G%): GOSUB 373: GOTO 366
  361. 361  GOSUB 139
  362. 362  IF PA% >0  AND LP% <1  THEN  PRINT  CHR$(12)
  363. 363  IF PA% >0  THEN 366
  364. 364  GOSUB 371: TEXT : HOME : GOSUB 158: IF LP% >0  THEN  RETURN 
  365. 365  GOSUB 121:V = 6:H = 12: GOSUB 155: PRINT "SET UP NEXT PAGE":V = V +3:H = 7: GOSUB 155: PRINT "PRESS "DQ$"RETURN"DQ$" WHEN READY...";:F2% = 0: GOSUB 74: GOSUB 370: PRINT 
  366. 366  IF LP% >0  THEN  RETURN 
  367. 367 TC = 0: IF G% >0  THEN I$ = WO$: GOSUB 139
  368. 368 CL = TC: IF P% < >3  THEN  RETURN 
  369. 369 I$ = A$ + STR$(G% +1):V = 24:H = 1: GOSUB 155: PRINT I$;" BEING PROCESSED...";:V = 1: GOSUB 155: RETURN 
  370. 370  GOSUB 121:V = 11:H = 14: GOSUB 155: PRINT "PRINTING...": POKE 32,24: POKE 33,1: POKE 34,10: POKE 35,11: HOME : PRINT D$;"PR#"P%: RETURN 
  371. 371  IF P% < >3  THEN  PRINT D$;"PR#0": RETURN 
  372. 372  GOSUB 374: RETURN 
  373. 373 I$ = I$ +" PRESS RETURN TO GO ON":V = 24:H = 1: GOSUB 155: PRINT I$;:H = 38:F2% = 0: GOSUB 75: GOSUB 374: PRINT D$;"PR#"P%: RETURN 
  374. 374  PRINT  CHR$(27); CHR$(17):: PRINT  CHR$(12): PRINT  CHR$(26) +"1": TEXT : HOME : VTAB 1: RETURN 
  375. 375  GOSUB 158: GOSUB 121:V = 10:H = 1: GOSUB 155: PRINT "  OOPS...A PROGRAM ERROR!": PRINT : PRINT "  PLEASE REPORT ERROR #" PEEK(222): PRINT : PRINT "  AT LINE NUMBER " PEEK(218) + PEEK(219) *256: END